Codemasters Artwork Disc ECTS 2000 ( UK)/Codemasters - Artwork Disc ECTS 2000 (UK).bin/pc/xtras/medial~1/setfx~1.dir/Internal_81_Slider Bar.ls

Text File | 1998-12-01 | 3.7 KB | 136 lines

property pThumbSprite, pFillSprite, pArrowsSprite, pTextSprite, pTextField, pCurVal, pExtraChar, pActive, pCallBackObj, pRefcon, pRange, pMin, pMax, pSliderLeft, pSliderWidth

on new me, propList
  set pFillSprite to getaProp(propList, #fillSprite)
  set pThumbSprite to getaProp(propList, #thumbSprite)
  set pArrowsSprite to getaProp(propList, #arrowsSprite)
  set pTextSprite to getaProp(propList, #textSprite)
  set pTextField to getaProp(propList, #textField)
  set pMin to getaProp(propList, #min)
  set pMax to getaProp(propList, #max)
  set pCurVal to getaProp(propList, #cur)
  set pSliderLeft to getaProp(propList, #left)
  set pSliderWidth to getaProp(propList, #width)
  set pExtraChar to getaProp(propList, #suffix)
  set pActive to getaProp(propList, #active)
  set pCallBackObj to getaProp(propList, #callback)
  set pRefcon to getaProp(propList, #ref)
  set pRange to pMax - pMin
  SetVal(me, pCurVal)
  SetEnabled(me, pActive)
  return me
end

on wait me, waitTime
  set t to the ticks
  repeat while the ticks < (t + waitTime)
  end repeat
end

on Arrows me
  if not pActive then
    exit
  end if
  set h1 to the locH of the clickLoc
  set h2 to the locH of sprite the clickOn
  if h1 < h2 then
    set side to "left"
    set d to -1
  else
    set side to "right"
    set d to 1
  end if
  set the member of sprite pArrowsSprite to member ("horizArrows" && side)
  set newVal to max(min(pCurVal + d, pMax), pMin)
  SetVal(me, newVal)
  if objectp(pCallBackObj) then
    DoDrag(pCallBackObj, pRefcon, newVal)
  end if
  updateStage()
  wait(me, 5)
  repeat while the stillDown
    if rollOver(pArrowsSprite) then
      set the member of sprite pArrowsSprite to member ("horizArrows" && side)
      set pCurVal to max(min(pCurVal + d, pMax), pMin)
    else
      set the member of sprite pArrowsSprite to member "horizArrows"
    end if
    SetVal(me, pCurVal)
    if objectp(pCallBackObj) then
      DoDrag(pCallBackObj, pRefcon, newVal)
    end if
    wait(me, 5)
  end repeat
  set the member of sprite pArrowsSprite to member "horizArrows"
  if objectp(pCallBackObj) then
    EndChange(pCallBackObj)
  end if
end

on Drag me
  if not pActive then
    exit
  end if
  repeat while the stillDown
    set H to min(max(the mouseH, pSliderLeft), pSliderLeft + pSliderWidth)
    set the locH of sprite pThumbSprite to H
    SetFill(me)
    updateStage()
    set loc to the locH of sprite pThumbSprite - pSliderLeft
    set pCurVal to (pRange * loc / pSliderWidth) + pMin
    TextOut(me)
    if objectp(pCallBackObj) then
      DoDrag(pCallBackObj, pRefcon, pCurVal)
    end if
  end repeat
  if objectp(pCallBackObj) then
    EndChange(pCallBackObj)
  end if
end

on SetFill me
  puppetSprite(pFillSprite, 1)
  set fillRect to the rect of sprite pFillSprite
  set the right of fillRect to the locH of sprite pThumbSprite
  set the left of fillRect to pSliderLeft
  set the rect of sprite pFillSprite to fillRect
end

on CalcVal me, numerator, denom, otherDenom
  set val to otherDenom * numerator / denom
  return val
end

on TextOut me
  if voidp(pCurVal) then
    put " " into field pTextField
  else
    put string(integer(pCurVal)) & pExtraChar into field pTextField
  end if
end

on SetVal me, newVal
  puppetSprite(pThumbSprite, 1)
  set pCurVal to newVal
  if voidp(newVal) then
    set newVal to pRange / 2
  end if
  TextOut(me)
  set loc to CalcVal(me, newVal - pMin, pRange, pSliderWidth)
  set the locH of sprite pThumbSprite to pSliderLeft + loc
  SetFill(me)
end

on SetEnabled me, enabled
  set pActive to enabled
  enableInterfaceElement(pFillSprite, enabled)
  enableInterfaceElement(pThumbSprite, enabled)
  enableInterfaceElement(pArrowsSprite, enabled)
  enableInterfaceElement(pTextSprite, enabled)
end

on Release me
  puppetSprite(pFillSprite, 0)
  puppetSprite(pThumbSprite, 0)
end